'======================================
'
' NOM: login.vbs
'
' AUTEUR: Jeremy Couture
' DATE: 15/03/05
'
' COMMENTAIRES: Script de connexion
' APPELS: toto.vbs
'
' VERSION: 1.1
' 
'======================================

'Déclaration des objets
Set WSHShell = CreateObject("WScript.Shell")
Set WSHNetwork = CreateObject("WScript.Network")
Set Shellprocess = WSHShell.Environment("PROCESS")
Set objFS = CreateObject("Scripting.FileSystemObject")

'Definition des constantes
Const serveurFIC = "\\Serveurdefichier\"
Const serveurPRN = "\\Serveurdimpression\"

'Definition des parametres réseau
With WSHNetwork
UserString=.Username
DomainString=.UserDomain
ComputerString=.Computername
End With

'Déclaration des objets utilisateur
Set UserObj = GetObject("WinNT://" & DomainString & "/" & UserString)
Set WMIService = GetObject("winmgmts:\\" & ComputerString & "\root\cimv2")

'Autorisation d'erreurs (i.e Serveur réseau non trouvé)
On Error Resume Next

'Récupération du controleur de domaine sur lequel le client s'est connecté
serveurAD = Shellprocess("LOGONSERVER") & "\"

'Synchronisation du temps
WSHShell.Run "NET TIME " & serveurAD & " /set /y",0

'Appel d'un fichier tiers toto.vbs place dans Netlogon
WSHShell.Run (serveurAD & "Netlogon\toto.vbs")

'Deconnexion des lecteurs reseaux existants
WSHShell.Run "NET USE /DELETE * /yes",0

'Connexion au lecteur réseau general de la societe
WSHNetwork.MapNetworkDrive "G:", serveurFIC & "General"

'Connexion au lecteur réseau personnel de l'utilisateur
WSHNetwork.MapNetworkDrive "U:", serveurFIC & UserString

'Telechargement du fond d'ecran pour GPO
If not objFS.FileExists("C:\Windows\Background.bmp") Then
		objFS.CopyFile serveurAD & "Netlogon\Bacground.bmp", "C:\Windows\Background.bmp"
End If

'Test d'appartenance à un groupe
For Each GroupObj In UserObj.Groups
    Select Case GroupObj.Name
    'Vérification du groupe de l'utilisateur
        Case "Informatique"
        		'Déroulement des spécifiques Informatique
            WSHNetwork.MapNetworkDrive "S:", serveurFIC & "Informatique"
            'Connexion à l'imprimante IMPINFO1
						WSHNetwork.AddWindowsPrinterConnection serveurPRN & "IMPINFO1"
        Case "Comptabilite"
        		'Déroulement des spécifiques Comptabilite
            WSHNetwork.MapNetworkDrive "N:", serveurFIC & "Comptabilite"
            'Connexion à l'imprimante IMPCPTA1
						WSHNetwork.AddWindowsPrinterConnection serveurPRN & "IMPCPTA1"
    End Select
Next

'Vidage des variables
Set UserObj = Nothing
Set WMIService = Nothing
Set objFS = Nothing
Set Shellprocess = Nothing
Set WSHNetwork = Nothing
Set WSHShell = Nothing

'Sortie du script
wscript.quit

'======================================
'
' NOM: hosts.vbs
'
' AUTEUR: Jeremy Couture
' DATE: 16/03/05
'
' COMMENTAIRES: Mise a jour du hosts
' APPELS: -
'
' VERSION: 1.0
' 
'======================================

'Declaration des objets
Set objFS = CreateObject("Scripting.FileSystemObject")

'Autorisation des erreurs (i.e Serveur réseau non trouvé)
On Error Resume Next

'Localisation du fichier hosts pour l'écraser
'Si OS XP/2003
If objFS.FileExists("C:\Windows\system32\drivers\etc\hosts") then
  objFS.CopyFile "\\serveur\partage\hosts", "C:\Windows\system32\drivers\etc\hosts"
End if

'Si OS 2000/NT
If objFS.FileExists("C:\Winnt\system32\drivers\etc\hosts") then
  objFS.CopyFile "\\serveur\partage\hosts", "C:\Winnt\system32\drivers\etc\hosts"
end if

'Si OS 9x
If objFS.FileExists("C:\Windows\hosts") then
  objFS.CopyFile "\\serveur\partage\hosts", "C:\Windows\hosts"
end if

'Vidage des variables
Set objFS = Nothing

'Sortie du script
wscript.quit